pythiaeRHIC/pythia/pytbbn.f

0001
0002
0003 C*********************************************************************
0004
0005 C...PYTBBN
0006 C...Calculates the three-body decay of gluinos into
0007 C...neutralinos and third generation fermions.
0008
0009       SUBROUTINE PYTBBN(I,NN,E,XMGLU,GAM)
0010
0011 C...Double precision and integer declarations.
0012       IMPLICIT DOUBLE PRECISION(A-H, O-Z)
0013       IMPLICIT INTEGER(I-N)
0014       INTEGER PYK,PYCHGE,PYCOMP
0015 C...Parameter statement to help give large particle numbers.
0016       PARAMETER (KSUSY1=1000000,KSUSY2=2000000,KTECHN=3000000,
0017      &KEXCIT=4000000,KDIMEN=5000000)
0018 C...Commonblocks.
0019       COMMON/PYDAT1/MSTU(200),PARU(200),MSTJ(200),PARJ(200)
0020       COMMON/PYDAT2/KCHG(500,4),PMAS(500,4),PARF(2000),VCKM(4,4)
0021       COMMON/PYMSSM/IMSS(0:99),RMSS(0:99)
0022       COMMON/PYSSMT/ZMIX(4,4),UMIX(2,2),VMIX(2,2),SMZ(4),SMW(2),
0023      &SFMIX(16,4),ZMIXI(4,4),UMIXI(2,2),VMIXI(2,2)
0024       SAVE /PYDAT1/,/PYDAT2/,/PYMSSM/,/PYSSMT/
0025
0026 C...Local variables.
0027       EXTERNAL PYSIMP,PYLAMF
0028       DOUBLE PRECISION PYSIMP,PYLAMF
0029       INTEGER LIN,NN
0030       DOUBLE PRECISION COSD,SIND,COSD2,SIND2,COS2D,SIN2D
0031       DOUBLE PRECISION HL,HR,FL,FR,HL2,HR2,FL2,FR2
0032       DOUBLE PRECISION XMS2(2),XM,XM2,XMG,XMG2,XMR,XMR2
0033       DOUBLE PRECISION SBAR,SMIN,SMAX,XMQA,W,GRS,G(0:6),SUMME(0:100)
0034       DOUBLE PRECISION FF,HH,HFL,HFR,HRFL,HLFR,XMQ4,XM24
0035       DOUBLE PRECISION XLN1,XLN2,B1,B2
0036       DOUBLE PRECISION E,XMGLU,GAM
0037       DOUBLE PRECISION HRB(4),HLB(4),FLB(4),FRB(4)
0038       SAVE HRB,HLB,FLB,FRB
0039       DOUBLE PRECISION ALPHAW,ALPHAS
0040       DOUBLE PRECISION HLT(4),HRT(4),FLT(4),FRT(4)
0041       SAVE HLT,HRT,FLT,FRT
0042       DOUBLE PRECISION AMN(4),AN(4,4),ZN(3)
0043       SAVE AMN,AN,ZN
0044       DOUBLE PRECISION AMBOT,SINC,COSC
0045       DOUBLE PRECISION AMTOP,SINA,COSA
0046       DOUBLE PRECISION SINW,COSW,TANW
0047       DOUBLE PRECISION ROT1(4,4)
0048       LOGICAL IFIRST
0049       SAVE IFIRST
0050       DATA IFIRST/.TRUE./
0051
0052       TANB=RMSS(5)
0053       SINB=TANB/SQRT(1D0+TANB**2)
0054       COSB=SINB/TANB
0055       XW=PARU(102)
0056       SINW=SQRT(XW)
0057       COSW=SQRT(1D0-XW)
0058       TANW=SINW/COSW
0059       AMW=PMAS(24,1)
0060       COSC=SFMIX(5,1)
0061       SINC=SFMIX(5,3)
0062       COSA=SFMIX(6,1)
0063       SINA=SFMIX(6,3)
0064       AMBOT=PYMRUN(5,XMGLU**2)
0065       AMTOP=PYMRUN(6,XMGLU**2)
0066       W2=SQRT(2D0)
0067       FAKT1=AMBOT/W2/AMW/COSB
0068       FAKT2=AMTOP/W2/AMW/SINB
0069       IF(IFIRST) THEN
0070         DO 110 II=1,4
0071           AMN(II)=SMZ(II)
0072           DO 100 J=1,4
0073             ROT1(II,J)=0D0
0074             AN(II,J)=0D0
0075   100     CONTINUE
0076   110   CONTINUE
0077         ROT1(1,1)=COSW
0078         ROT1(1,2)=-SINW
0079         ROT1(2,1)=-ROT1(1,2)
0080         ROT1(2,2)=ROT1(1,1)
0081         ROT1(3,3)=COSB
0082         ROT1(3,4)=SINB
0083         ROT1(4,3)=-ROT1(3,4)
0084         ROT1(4,4)=ROT1(3,3)
0085         DO 140 II=1,4
0086           DO 130 J=1,4
0087             DO 120 JJ=1,4
0088               AN(II,J)=AN(II,J)+ZMIX(II,JJ)*ROT1(JJ,J)
0089   120       CONTINUE
0090   130     CONTINUE
0091   140   CONTINUE
0092         DO 150 J=1,4
0093           ZN(1)=-FAKT2*(-SINB*AN(J,3)+COSB*AN(J,4))
0094           ZN(2)=-2D0*W2/3D0*SINW*(TANW*AN(J,2)-AN(J,1))
0095           ZN(3)=-2*W2/3D0*SINW*AN(J,1)-W2*(0.5D0-2D0/3D0*
0096      &    XW)*AN(J,2)/COSW
0097           HRT(J)=ZN(1)*COSA-ZN(3)*SINA
0098           HLT(J)=ZN(1)*COSA+ZN(2)*SINA
0099           FLT(J)=ZN(3)*COSA+ZN(1)*SINA
0100           FRT(J)=ZN(2)*COSA-ZN(1)*SINA
0101 C          FLU(J)=ZN(3)
0102 C          FRU(J)=ZN(2)
0103           ZN(1)=-FAKT1*(COSB*AN(J,3)+SINB*AN(J,4))
0104           ZN(2)=W2/3D0*SINW*(TANW*AN(J,2)-AN(J,1))
0105           ZN(3)=W2/3D0*SINW*AN(J,1)+W2*(0.5D0-XW/3D0)*AN(J,2)/COSW
0106           HRB(J)=ZN(1)*COSC-ZN(3)*SINC
0107           HLB(J)=ZN(1)*COSC+ZN(2)*SINC
0108           FLB(J)=ZN(3)*COSC+ZN(1)*SINC
0109           FRB(J)=ZN(2)*COSC-ZN(1)*SINC
0110 C          FLD(J)=ZN(3)
0111 C          FRD(J)=ZN(2)
0112   150   CONTINUE
0113 C        AMST(1)=PMAS(PYCOMP(KSUSY1+6),1)
0114 C        AMST(2)=PMAS(PYCOMP(KSUSY2+6),1)
0115 C        AMSB(1)=PMAS(PYCOMP(KSUSY1+5),1)
0116 C        AMSB(2)=PMAS(PYCOMP(KSUSY2+5),1)
0117         IFIRST=.FALSE.
0118       ENDIF
0119
0120       IF(NINT(3D0*E).EQ.2) THEN
0121         HL=HLT(I)
0122         HR=HRT(I)
0123         FL=FLT(I)
0124         FR=FRT(I)
0125         COSD=SFMIX(6,1)
0126         SIND=SFMIX(6,3)
0127         XMS2(1)=PMAS(PYCOMP(KSUSY1+6),1)**2
0128         XMS2(2)=PMAS(PYCOMP(KSUSY2+6),1)**2
0129         XM=PMAS(6,1)
0130       ELSE
0131         HL=HLB(I)
0132         HR=HRB(I)
0133         FL=FLB(I)
0134         FR=FRB(I)
0135         COSD=SFMIX(5,1)
0136         SIND=SFMIX(5,3)
0137         XMS2(1)=PMAS(PYCOMP(KSUSY1+5),1)**2
0138         XMS2(2)=PMAS(PYCOMP(KSUSY2+5),1)**2
0139         XM=PMAS(5,1)
0140       ENDIF
0141       COSD2=COSD*COSD
0142       SIND2=SIND*SIND
0143       COS2D=COSD2-SIND2
0144       SIN2D=SIND*COSD*2D0
0145       HL2=HL*HL
0146       HR2=HR*HR
0147       FL2=FL*FL
0148       FR2=FR*FR
0149       FF=FL*FR
0150       HH=HL*HR
0151       HFL=HL*FL
0152       HFR=HR*FR
0153       HRFL=HR*FL
0154       HLFR=HL*FR
0155       XM2=XM*XM
0156       XMG=XMGLU
0157       XMG2=XMG*XMG
0158       ALPHAW=PYALEM(XMG2)
0159       ALPHAS=PYALPS(XMG2)
0160       XMR=AMN(I)
0161       XMR2=XMR*XMR
0162       XMQ4=XMG*XM2*XMR
0163       XM24=(XMG2+XM2)*(XM2+XMR2)
0164       SMIN=4D0*XM2
0165       SMAX=(XMG-ABS(XMR))**2
0166       XMQA=XMG2+2D0*XM2+XMR2
0167       DO 170 LIN=1,NN-1
0168         SBAR=SMIN+DBLE(LIN)*(SMAX-SMIN)/DBLE(NN)
0169         GRS=SBAR-XMQA
0170         W=PYLAMF(XMG2,XMR2,SBAR)*(0.25D0-XM2/SBAR)
0171         W=DSQRT(W)
0172         XLN1=LOG(ABS((GRS/2D0+XMS2(1)-W)/(GRS/2D0+XMS2(1)+W)))
0173         XLN2=LOG(ABS((GRS/2D0+XMS2(2)-W)/(GRS/2D0+XMS2(2)+W)))
0174         B1=1D0/(GRS/2D0+XMS2(1)-W)-1D0/(GRS/2D0+XMS2(1)+W)
0175         B2=1D0/(GRS/2D0+XMS2(2)-W)-1D0/(GRS/2D0+XMS2(2)+W)
0176         G(0)=-2D0*(HL2+FL2+HR2+FR2+(HFR-HFL)*SIN2D
0177      &  +2D0*(FF*SIND2-HH*COSD2))*W
0178         G(1)=((HL2+FL2)*(XMQA-2D0*XMS2(1)-2D0*XM*XMG*SIN2D)
0179      &  +4D0*HFL*XM*XMR)*XLN1
0180      &  +((HL2+FL2)*((XMQA-XMS2(1))*XMS2(1)-XM24
0181      &  +2D0*XM*XMG*(XM2+XMR2-XMS2(1))*SIN2D)
0182      &  -4D0*HFL*XMR*XM*(XMG2+XM2-XMS2(1))
0183      &  +8D0*HFL*XMQ4*SIN2D)*B1
0184         G(2)=((HR2+FR2)*(XMQA-2D0*XMS2(2)+2D0*XM*XMG*SIN2D)
0185      &  +4D0*HFR*XMR*XM)*XLN2
0186      &  +((HR2+FR2)*((XMQA-XMS2(2))*XMS2(2)-XM24
0187      &  +2D0*XMG*XM*SIN2D*(XMS2(2)-XM2-XMR2))
0188      &  +4D0*HFR*XM*XMR*(XMS2(2)-XMG2-XM2)
0189      &  -8D0*HFR*XMQ4*SIN2D)*B2
0190         G(3)=(2D0*HFL*SIN2D*(XMS2(1)*(GRS+XMS2(1))+XM2*(SBAR-XMG2-XMR2)
0191      &  +XMG2*XMR2+XM2*XM2)-2D0*XMR*XMG*(HL2*SIND2+FL2*COSD2)*SBAR
0192      &  -2D0*XMG*XM*HFL*(SBAR+XMR2-XMG2)
0193      &  +XMR*XM*(HL2+FL2)*SIN2D*(SBAR+XMG2-XMR2)
0194      &  -4D0*XMQ4*(HL2-FL2)*COS2D)/(GRS+2D0*XMS2(1))*XLN1
0195         G(4)=4D0*COS2D*XM*XMG/(XMS2(1)-XMS2(2))*
0196      &  (((HLFR+HRFL)*(XM2+XMR2)+2D0*XM*XMR*(HH+FF))*(XLN1-XLN2)
0197      &  +(HLFR+HRFL)*(XMS2(2)*XLN2-XMS2(1)*XLN1))
0198         G(5)=(2D0*(HH*COSD2-FF*SIND2)
0199      &  *((XMS2(2)*(XMS2(2)+GRS)+XM2*XM2+XMG2*XMR2)*XLN2
0200      &  +(XMS2(1)*(XMS2(1)+GRS)+XM2*XM2+XMG2*XMR2)*XLN1)
0201      &  +XM*((HH-FF)*SIN2D*XMG-(HRFL-HLFR)*XMR)
0202      &  *((GRS+XMS2(1)*2D0)*XLN1-(GRS+XMS2(2)*2D0)*XLN2)
0203      &  +((HRFL-HLFR)*XMR*(SIN2D*XMG*(SBAR-4D0*XM2)
0204      &  +COS2D*XM*(SBAR+XMG2-XMR2))
0205      &  +2D0*(FF*COSD2-HH*SIND2)*XM2*(SBAR-XMG2-XMR2))
0206      &  *(XLN1+XLN2))/(GRS+XMS2(1)+XMS2(2))
0207         G(6)=(-2D0*HFR*SIN2D*(XMS2(2)*(GRS+XMS2(2))+XM2*(SBAR-XMG2-XMR2)
0208      &  +XMG2*XMR2+XM2*XM2)-2D0*XMR*XMG*(HR2*SIND2+FR2*COSD2)*SBAR
0209      &  -2D0*XMG*XM*HFR*(SBAR+XMR2-XMG2)
0210      &  -XMR*XM*(HR2+FR2)*SIN2D*(SBAR+XMG2-XMR2)
0211      &  -4D0*XMQ4*(HR2-FR2)*COS2D)/(GRS+2D0*XMS2(2))*XLN2
0212         SUMME(LIN)=0D0
0213         DO 160 J=0,6
0214           SUMME(LIN)=SUMME(LIN)+G(J)
0215   160   CONTINUE
0216   170 CONTINUE
0217       SUMME(0)=0D0
0218       SUMME(NN)=0D0
0219       GAM = ALPHAW * ALPHAS * PYSIMP(SUMME,SMIN,SMAX,NN)
0220      &/ (16D0 * PARU(1) * PARU(102) * XMGLU**3)
0221
0222       RETURN
0223       END