pythiaeRHIC/pythia/pysubh.f

0001
0002 C*********************************************************************
0003
0004 C...PYSUBH
0005 C...This routine computes the renormalization group improved
0006 C...values of Higgs masses and couplings in the MSSM.
0007
0008 C...Program based on the work by M. Carena, J.R. Espinosa,
0009 c...M. Quiros and C.E.M. Wagner, CERN-preprint CERN-TH/95-45
0010
0011 C...Input: MA,TANB = TAN(BETA),MQ,MUR,MTOP,AU,AD,MU
0012 C...All masses in GeV units. MA is the CP-odd Higgs mass,
0013 C...MTOP is the physical top mass, MQ and MUR are the soft
0014 C...supersymmetry breaking mass parameters of left handed
0015 C...and right handed stops respectively, AU and AD are the
0016 C...stop and sbottom trilinear soft breaking terms,
0017 C...respectively,  and MU is the supersymmetric
0018 C...Higgs mass parameter. We use the  conventions from
0019 C...the physics report of Haber and Kane: left right
0020 C...stop mixing term proportional to (AU - MU/TANB)
0021 C...We use as input TANB defined at the scale MTOP
0022
0023 C...Output: MH,HM,MHCH, SA = SIN(ALPHA), CA= COS(ALPHA), TANBA
0024 C...where MH and HM are the lightest and heaviest CP-even
0025 C...Higgs masses, MHCH is the charged Higgs mass and
0026 C...ALPHA is the Higgs mixing angle
0027 C...TANBA is the angle TANB at the CP-odd Higgs mass scale
0028
0029 C...Range of validity:
0030 C...(STOP1**2 - STOP2**2)/(STOP2**2 + STOP1**2) < 0.5
0031 C...(SBOT1**2 - SBOT2**2)/(SBOT2**2 + SBOT2**2) < 0.5
0032 C...where STOP1, STOP2, SBOT1 and SBOT2 are the stop and
0033 C...are the sbottom  mass eigenvalues, respectively. This
0034 C...range automatically excludes the existence of tachyons.
0035 C...For the charged Higgs mass computation, the method is
0036 C...valid if
0037 C...2 * |MB * AD* TANB|  < M_SUSY**2,  2 * |MTOP * AU| < M_SUSY**2
0038 C...2 * |MB * MU * TANB| < M_SUSY**2,  2 * |MTOP * MU| < M_SUSY**2
0039 C...where M_SUSY**2 is the average of the squared stop mass
0040 C...eigenvalues, M_SUSY**2 = (STOP1**2 + STOP2**2)/2. The sbottom
0041 C...masses have been assumed to be of order of the stop ones
0042 C...M_SUSY**2 = (MQ**2 + MUR**2)*0.5 + MTOP**2
0043
0044       SUBROUTINE PYSUBH (XMA,TANB,XMQ,XMUR,XMTOP,AU,AD,XMU,XMH,XHM,
0045      &XMHCH,SA,CA,TANBA)
0046
0047 C...Double precision and integer declarations.
0048       IMPLICIT DOUBLE PRECISION(A-H, O-Z)
0049       IMPLICIT INTEGER(I-N)
0050       INTEGER PYK,PYCHGE,PYCOMP
0051 C...Parameter statement to help give large particle numbers.
0052       PARAMETER (KSUSY1=1000000,KSUSY2=2000000,KTECHN=3000000,
0053      &KEXCIT=4000000,KDIMEN=5000000)
0054 C...Commonblocks.
0055       COMMON/PYDAT1/MSTU(200),PARU(200),MSTJ(200),PARJ(200)
0056       COMMON/PYDAT2/KCHG(500,4),PMAS(500,4),PARF(2000),VCKM(4,4)
0057       COMMON/PYHTRI/HHH(7)
0058       SAVE /PYDAT1/,/PYDAT2/
0059
0060 C...Local variables.
0061       DOUBLE PRECISION PYALEM,PYALPS
0062       DOUBLE PRECISION TANB,XMQ,XMUR,XMTOP,AU,AD,XMU,XMH,XHM
0063       DOUBLE PRECISION XMHCH,SA,CA
0064       DOUBLE PRECISION XMA,AEM,ALP1,ALP2,ALPH3Z,V,PI
0065       DOUBLE PRECISION Q02
0066       DOUBLE PRECISION TANBA,TANBT,XMB,ALP3
0067       DOUBLE PRECISION RMTOP,XMS,T,SINB,COSB
0068       DOUBLE PRECISION XLAM1,XLAM2,XLAM3,XLAM4,XLAM5,XLAM6
0069       DOUBLE PRECISION XLAM7,XAU,XAD,G1,G2,G3,HU,HD,HU2
0070       DOUBLE PRECISION HD2,HU4,HD4,SINBT,COSBT
0071       DOUBLE PRECISION TRM2,DETM2,XMH2,XHM2,XMHCH2
0072       DOUBLE PRECISION SINALP,COSALP,AUD,PI2,XMS2,XMS4,AD2
0073       DOUBLE PRECISION AU2,XMU2,XMZ,XMS3
0074
0075       XMZ = PMAS(23,1)
0076       Q02=XMZ**2
0077       AEM=PYALEM(Q02)
0078       ALP1=AEM/(1D0-PARU(102))
0079       ALP2=AEM/PARU(102)
0080       ALPH3Z=PYALPS(Q02)
0081
0082       ALP1 = 0.0101D0
0083       ALP2 = 0.0337D0
0084       ALPH3Z = 0.12D0
0085
0086       V = 174.1D0
0087       PI = PARU(1)
0088       TANBA = TANB
0089       TANBT = TANB
0090
0091 C...MBOTTOM(MTOP) = 3. GEV
0092       XMB = PYMRUN(5,XMTOP**2)
0093       ALP3 = ALPH3Z/(1D0 +(11D0 - 10D0/3D0)/4D0/PI*ALPH3Z*
0094      &LOG(XMTOP**2/XMZ**2))
0095
0096 C...RMTOP= RUNNING TOP QUARK MASS
0097       RMTOP = XMTOP/(1D0+4D0*ALP3/3D0/PI)
0098       XMS = ((XMQ**2 + XMUR**2)/2D0 + XMTOP**2)**0.5D0
0099       T = LOG(XMS**2/XMTOP**2)
0100       SINB = TANB/((1D0 + TANB**2)**0.5D0)
0101       COSB = SINB/TANB
0102 C...IF(MA.LE.XMTOP) TANBA = TANBT
0103       IF(XMA.GT.XMTOP)
0104      &TANBA = TANBT*(1D0-3D0/32D0/PI**2*
0105      &(RMTOP**2/V**2/SINB**2-XMB**2/V**2/COSB**2)*
0106      &LOG(XMA**2/XMTOP**2))
0107
0108       SINBT = TANBT/SQRT(1D0 + TANBT**2)
0109       COSBT = 1D0/SQRT(1D0 + TANBT**2)
0110 C      COS2BT = (TANBT**2 - 1D0)/(TANBT**2 + 1D0)
0111       G1 = SQRT(ALP1*4D0*PI)
0112       G2 = SQRT(ALP2*4D0*PI)
0113       G3 = SQRT(ALP3*4D0*PI)
0114       HU = RMTOP/V/SINBT
0115       HD =  XMB/V/COSBT
0116       HU2=HU*HU
0117       HD2=HD*HD
0118       HU4=HU2*HU2
0119       HD4=HD2*HD2
0120       AU2=AU**2
0121       AD2=AD**2
0122       XMS2=XMS**2
0123       XMS3=XMS**3
0124       XMS4=XMS2*XMS2
0125       XMU2=XMU*XMU
0126       PI2=PI*PI
0127
0128       XAU = (2D0*AU2/XMS2)*(1D0 - AU2/12D0/XMS2)
0129       XAD = (2D0*AD2/XMS2)*(1D0 - AD2/12D0/XMS2)
0130       AUD = (-6D0*XMU2/XMS2 - ( XMU2- AD*AU)**2/XMS4
0131      &+ 3D0*(AU + AD)**2/XMS2)/6D0
0132       XLAM1 = ((G1**2 + G2**2)/4D0)*(1D0-3D0*HD2*T/8D0/PI2)
0133      &+(3D0*HD4/8D0/PI2) * (T + XAD/2D0 + (3D0*HD2/2D0 + HU2/2D0
0134      &- 8D0*G3**2) * (XAD*T + T**2)/16D0/PI2)
0135      &-(3D0*HU4* XMU**4/96D0/PI2/XMS4) * (1+ (9D0*HU2 -5D0* HD2
0136      &-  16D0*G3**2) *T/16D0/PI2)
0137       XLAM2 = ((G1**2 + G2**2)/4D0)*(1D0-3D0*HU2*T/8D0/PI2)
0138      &+(3D0*HU4/8D0/PI2) * (T + XAU/2D0 + (3D0*HU2/2D0 + HD2/2D0
0139      &- 8D0*G3**2) * (XAU*T + T**2)/16D0/PI2)
0140      &-(3D0*HD4* XMU**4/96D0/PI2/XMS4) * (1+ (9D0*HD2 -5D0* HU2
0141      &-  16D0*G3**2) *T/16D0/PI2)
0142       XLAM3 = ((G2**2 - G1**2)/4D0)*(1D0-3D0*
0143      &(HU2 + HD2)*T/16D0/PI2)
0144      &+(6D0*HU2*HD2/16D0/PI2) * (T + AUD/2D0 + (HU2 + HD2
0145      &- 8D0*G3**2) * (AUD*T + T**2)/16D0/PI2)
0146      &+(3D0*HU4/96D0/PI2) * (3D0*XMU2/XMS2 - XMU2*AU2/
0147      &XMS4)* (1D0+ (6D0*HU2 -2D0* HD2/2D0
0148      &-  16D0*G3**2) *T/16D0/PI2)
0149      &+(3D0*HD4/96D0/PI2) * (3D0*XMU2/XMS2 - XMU2*AD2/
0150      &XMS4)*(1D0+ (6D0*HD2 -2D0* HU2
0151      &-  16D0*G3**2) *T/16D0/PI2)
0152       XLAM4 = (- G2**2/2D0)*(1D0-3D0*(HU2 + HD2)*T/16D0/PI2)
0153      &-(6D0*HU2*HD2/16D0/PI2) * (T + AUD/2D0 + (HU2 + HD2
0154      &- 8D0*G3**2) * (AUD*T + T**2)/16D0/PI2)
0155      &+(3D0*HU4/96D0/PI2) * (3D0*XMU2/XMS2 - XMU2*AU2/
0156      &XMS4)*
0157      &(1+ (6D0*HU2 -2D0* HD2
0158      &-  16D0*G3**2) *T/16D0/PI2)
0159      &+(3D0*HD4/96D0/PI2) * (3D0*XMU2/XMS2 - XMU2*AD2/
0160      &XMS4)*
0161      &(1+ (6D0*HD2 -2D0* HU2/2D0
0162      &-  16D0*G3**2) *T/16D0/PI2)
0163       XLAM5 = -(3D0*HU4* XMU2*AU2/96D0/PI2/XMS4) *
0164      &(1- (2D0*HD2 -6D0* HU2 + 16D0*G3**2) *T/16D0/PI2)
0165      &-(3D0*HD4* XMU2*AD2/96D0/PI2/XMS4) *
0166      &(1- (2D0*HU2 -6D0* HD2 + 16D0*G3**2) *T/16D0/PI2)
0167       XLAM6 = (3D0*HU4* XMU**3*AU/96D0/PI2/XMS4) *
0168      &(1- (7D0*HD2/2D0 -15D0* HU2/2D0 + 16D0*G3**2) *T/16D0/PI2)
0169      &+(3D0*HD4* XMU *(AD**3/XMS3 - 6D0*AD/XMS )/96D0/PI2/XMS) *
0170      &(1- (HU2/2D0 -9D0* HD2/2D0 + 16D0*G3**2) *T/16D0/PI2)
0171       XLAM7 = (3D0*HD4* XMU**3*AD/96D0/PI2/XMS4) *
0172      &(1- (7D0*HU2/2D0 -15D0* HD2/2D0 + 16D0*G3**2) *T/16D0/PI2)
0173      &+(3D0*HU4* XMU *(AU**3/XMS3 - 6D0*AU/XMS )/96D0/PI2/XMS) *
0174      &(1- (HD2/2D0 -9D0* HU2/2D0 + 16D0*G3**2) *T/16D0/PI2)
0175       HHH(1)=XLAM1
0176       HHH(2)=XLAM2
0177       HHH(3)=XLAM3
0178       HHH(4)=XLAM4
0179       HHH(5)=XLAM5
0180       HHH(6)=XLAM6
0181       HHH(7)=XLAM7
0182       TRM2 = XMA**2 + 2D0*V**2* (XLAM1* COSBT**2 +
0183      &2D0* XLAM6*SINBT*COSBT
0184      &+ XLAM5*SINBT**2 + XLAM2* SINBT**2 + 2D0* XLAM7*SINBT*COSBT
0185      &+ XLAM5*COSBT**2)
0186       DETM2 = 4D0*V**4*(-(SINBT*COSBT*(XLAM3 + XLAM4) +
0187      &XLAM6*COSBT**2
0188      &+ XLAM7* SINBT**2)**2 + (XLAM1* COSBT**2 +
0189      &2D0* XLAM6* COSBT*SINBT
0190      &+ XLAM5*SINBT**2)*(XLAM2* SINBT**2 +2D0* XLAM7* COSBT*SINBT
0191      &+ XLAM5*COSBT**2)) + XMA**2*2D0*V**2 *
0192      &((XLAM1* COSBT**2 +2D0*
0193      &XLAM6* COSBT*SINBT + XLAM5*SINBT**2)*COSBT**2 +
0194      &(XLAM2* SINBT**2 +2D0* XLAM7* COSBT*SINBT + XLAM5*COSBT**2)
0195      &*SINBT**2
0196      &+2D0*SINBT*COSBT* (SINBT*COSBT*(XLAM3
0197      &+ XLAM4) + XLAM6*COSBT**2
0198      &+ XLAM7* SINBT**2))
0199
0200       XMH2 = (TRM2 - SQRT(TRM2**2 - 4D0* DETM2))/2D0
0201       XHM2 = (TRM2 + SQRT(TRM2**2 - 4D0* DETM2))/2D0
0202       XHM = SQRT(XHM2)
0203       XMH = SQRT(XMH2)
0204       XMHCH2 = XMA**2 + (XLAM5 - XLAM4)* V**2
0205       XMHCH = SQRT(XMHCH2)
0206
0207       SINALP = SQRT(((TRM2**2 - 4D0* DETM2)**0.5D0) -
0208      &((2D0*V**2*(XLAM1* COSBT**2 + 2D0*
0209      &XLAM6* COSBT*SINBT
0210      &+ XLAM5*SINBT**2) + XMA**2*SINBT**2)
0211      &- (2D0*V**2*(XLAM2* SINBT**2 +2D0* XLAM7* COSBT*SINBT
0212      &+ XLAM5*COSBT**2) + XMA**2*COSBT**2)))/
0213      &SQRT(((TRM2**2 - 4D0* DETM2)**0.5D0))/2D0**0.5D0
0214
0215       COSALP = (2D0*(2D0*V**2*(SINBT*COSBT*(XLAM3 + XLAM4) +
0216      &XLAM6*COSBT**2 + XLAM7* SINBT**2) -
0217      &XMA**2*SINBT*COSBT))/2D0**0.5D0/
0218      &SQRT(((TRM2**2 - 4D0* DETM2)**0.5D0)*
0219      &(((TRM2**2 - 4D0* DETM2)**0.5D0) -
0220      &((2D0*V**2*(XLAM1* COSBT**2 + 2D0*
0221      &XLAM6* COSBT*SINBT
0222      &+ XLAM5*SINBT**2) + XMA**2*SINBT**2)
0223      &- (2D0*V**2*(XLAM2* SINBT**2 +2D0* XLAM7* COSBT*SINBT
0224      &+ XLAM5*COSBT**2) + XMA**2*COSBT**2))))
0225
0226       SA = -SINALP
0227       CA = -COSALP
0228
0229   100 CONTINUE
0230
0231       RETURN
0232       END