pythiaeRHIC/pythia/pymewt.f

0001
0002 C*********************************************************************
0003
0004 C...PYMEWT
0005 C...Calculates actual ME weight in some initial-state showers.
0006 C...Inparameter MECOR: kind of hard scattering process
0007 C...            IFLCB: flavour combination of branching,
0008 C...                   1 for fermion -> fermion,
0009 C...                   2 for gluon/photon -> fermion
0010 C...                   3 for fermion -> gluon/photon,
0011 C...                   4 for gluon -> gluon
0012 C...            Q2:    Q2 value of shower branching
0013 C...            Z:     Z value of branching
0014 C...In+outparameter PHIBR: azimuthal angle of branching
0015 C...Outparameter WTME: actual ME weight
0016
0017       SUBROUTINE PYMEWT(MECOR,IFLCB,Q2,Z,PHIBR,WTME)
0018
0019 C...Double precision and integer declarations.
0020       IMPLICIT DOUBLE PRECISION(A-H, O-Z)
0021       IMPLICIT INTEGER(I-N)
0022       INTEGER PYK,PYCHGE,PYCOMP
0023 C...Commonblocks.
0024       COMMON/PYJETS/N,NPAD,K(4000,5),P(4000,5),V(4000,5)
0025       COMMON/PYDAT1/MSTU(200),PARU(200),MSTJ(200),PARJ(200)
0026       COMMON/PYPARS/MSTP(200),PARP(200),MSTI(200),PARI(200)
0027       COMMON/PYINT1/MINT(400),VINT(400)
0028       COMMON/PYINT2/ISET(500),KFPR(500,2),COEF(500,20),ICOL(40,4,2)
0029       SAVE /PYJETS/,/PYDAT1/,/PYPARS/,/PYINT1/,/PYINT2/
0030
0031 C...Default output.
0032       WTME=1D0
0033
0034 C...Define kinematics of shower branching in Mandelstam variables.
0035       SQM=VINT(44)
0036       SH=SQM/Z
0037       TH=-Q2
0038       UH=Q2-SQM*(1D0-Z)/Z
0039
0040 C...Matrix-element corrections for f + fbar -> s-channel vector boson.
0041       IF(MECOR.EQ.1) THEN
0042         IF(IFLCB.EQ.1) THEN
0043           WTME=(TH**2+UH**2+2D0*SQM*SH)/(SH**2+SQM**2)
0044         ELSEIF(IFLCB.EQ.2) THEN
0045           WTME=(SH**2+UH**2+2D0*SQM*TH)/((SH-SQM)**2+SQM**2)
0046         ENDIF
0047
0048 C...Matrix-element corrections for g + g -> Higgs (h0, H0, A0).
0049       ELSEIF(MECOR.EQ.2) THEN
0050         IF(IFLCB.EQ.3) THEN
0051           WTME=(SH**2+UH**2)/(SH**2+(SH-SQM)**2)
0052         ELSEIF(IFLCB.EQ.4) THEN
0053           WTME=0.5D0*(SH**4+UH**4+TH**4+SQM**4)/(SH**2-SQM*(SH-SQM))**2
0054         ENDIF
0055
0056 C...Matrix-element corrections for q + qbar -> Higgs (h0)
0057       ELSEIF(MECOR.EQ.3) THEN
0058         IF(IFLCB.EQ.2) THEN
0059           WTME=(SH**2+TH**2+2D0*(SQM-TH)*(SQM-SH))/
0060      1      (SH**2+2D0*SQM*(SQM-SH))
0061         ENDIF
0062       ENDIF
0063
0064       RETURN
0065       END