pythiaeRHIC/pythia/pyeevt.f

0001
0002 C*********************************************************************
0003
0004 C...PYEEVT
0005 C...Handles the generation of an e+e- annihilation jet event.
0006
0007       SUBROUTINE PYEEVT(KFL,ECM)
0008
0009 C...Double precision and integer declarations.
0010       IMPLICIT DOUBLE PRECISION(A-H, O-Z)
0011       IMPLICIT INTEGER(I-N)
0012       INTEGER PYK,PYCHGE,PYCOMP
0013 C...Commonblocks.
0014       COMMON/PYJETS/N,NPAD,K(4000,5),P(4000,5),V(4000,5)
0015       COMMON/PYDAT1/MSTU(200),PARU(200),MSTJ(200),PARJ(200)
0016       COMMON/PYDAT2/KCHG(500,4),PMAS(500,4),PARF(2000),VCKM(4,4)
0017       SAVE /PYJETS/,/PYDAT1/,/PYDAT2/
0018
0019 C...Check input parameters.
0020       IF(MSTU(12).NE.12345) CALL PYLIST(0)
0021       IF(KFL.LT.0.OR.KFL.GT.8) THEN
0022         CALL PYERRM(16,'(PYEEVT:) called with unknown flavour code')
0023         IF(MSTU(21).GE.1) RETURN
0024       ENDIF
0025       IF(KFL.LE.5) ECMMIN=PARJ(127)+2.02D0*PARF(100+MAX(1,KFL))
0026       IF(KFL.GE.6) ECMMIN=PARJ(127)+2.02D0*PMAS(KFL,1)
0027       IF(ECM.LT.ECMMIN) THEN
0028         CALL PYERRM(16,'(PYEEVT:) called with too small CM energy')
0029         IF(MSTU(21).GE.1) RETURN
0030       ENDIF
0031
0032 C...Check consistency of MSTJ options set.
0033       IF(MSTJ(109).EQ.2.AND.MSTJ(110).NE.1) THEN
0034         CALL PYERRM(6,
0035      &  '(PYEEVT:) MSTJ(109) value requires MSTJ(110) = 1')
0036         MSTJ(110)=1
0037       ENDIF
0038       IF(MSTJ(109).EQ.2.AND.MSTJ(111).NE.0) THEN
0039         CALL PYERRM(6,
0040      &  '(PYEEVT:) MSTJ(109) value requires MSTJ(111) = 0')
0041         MSTJ(111)=0
0042       ENDIF
0043
0044 C...Initialize alpha_strong and total cross-section.
0045       MSTU(111)=MSTJ(108)
0046       IF(MSTJ(108).EQ.2.AND.(MSTJ(101).EQ.0.OR.MSTJ(101).EQ.1))
0047      &MSTU(111)=1
0048       PARU(112)=PARJ(121)
0049       IF(MSTU(111).EQ.2) PARU(112)=PARJ(122)
0050       IF(MSTJ(116).GT.0.AND.(MSTJ(116).GE.2.OR.ABS(ECM-PARJ(151)).GE.
0051      &PARJ(139).OR.10*MSTJ(102)+KFL.NE.MSTJ(119))) CALL PYXTEE(KFL,ECM,
0052      &XTOT)
0053       IF(MSTJ(116).GE.3) MSTJ(116)=1
0054       PARJ(171)=0D0
0055
0056 C...Add initial e+e- to event record (documentation only).
0057       NTRY=0
0058   100 NTRY=NTRY+1
0059       IF(NTRY.GT.100) THEN
0060         CALL PYERRM(14,'(PYEEVT:) caught in an infinite loop')
0061         RETURN
0062       ENDIF
0063       MSTU(24)=0
0064       NC=0
0065       IF(MSTJ(115).GE.2) THEN
0066         NC=NC+2
0067         CALL PY1ENT(NC-1,11,0.5D0*ECM,0D0,0D0)
0068         K(NC-1,1)=21
0069         CALL PY1ENT(NC,-11,0.5D0*ECM,PARU(1),0D0)
0070         K(NC,1)=21
0071       ENDIF
0072
0073 C...Radiative photon (in initial state).
0074       MK=0
0075       ECMC=ECM
0076       IF(MSTJ(107).GE.1.AND.MSTJ(116).GE.1) CALL PYRADK(ECM,MK,PAK,
0077      &THEK,PHIK,ALPK)
0078       IF(MK.EQ.1) ECMC=SQRT(ECM*(ECM-2D0*PAK))
0079       IF(MSTJ(115).GE.1.AND.MK.EQ.1) THEN
0080         NC=NC+1
0081         CALL PY1ENT(NC,22,PAK,THEK,PHIK)
0082         K(NC,3)=MIN(MSTJ(115)/2,1)
0083       ENDIF
0084
0085 C...Virtual exchange boson (gamma or Z0).
0086       IF(MSTJ(115).GE.3) THEN
0087         NC=NC+1
0088         KF=22
0089         IF(MSTJ(102).EQ.2) KF=23
0090         MSTU10=MSTU(10)
0091         MSTU(10)=1
0092         P(NC,5)=ECMC
0093         CALL PY1ENT(NC,KF,ECMC,0D0,0D0)
0094         K(NC,1)=21
0095         K(NC,3)=1
0096         MSTU(10)=MSTU10
0097       ENDIF
0098
0099 C...Choice of flavour and jet configuration.
0100       CALL PYXKFL(KFL,ECM,ECMC,KFLC)
0101       IF(KFLC.EQ.0) GOTO 100
0102       CALL PYXJET(ECMC,NJET,CUT)
0103       KFLN=21
0104       IF(NJET.EQ.4) CALL PYX4JT(NJET,CUT,KFLC,ECMC,KFLN,X1,X2,X4,
0105      &X12,X14)
0106       IF(NJET.EQ.3) CALL PYX3JT(NJET,CUT,KFLC,ECMC,X1,X3)
0107       IF(NJET.EQ.2) MSTJ(120)=1
0108
0109 C...Fill jet configuration and origin.
0110       IF(NJET.EQ.2.AND.MSTJ(101).NE.5) CALL PY2ENT(NC+1,KFLC,-KFLC,ECMC)
0111       IF(NJET.EQ.2.AND.MSTJ(101).EQ.5) CALL PY2ENT(-(NC+1),KFLC,-KFLC,
0112      &ECMC)
0113       IF(NJET.EQ.3) CALL PY3ENT(NC+1,KFLC,21,-KFLC,ECMC,X1,X3)
0114       IF(NJET.EQ.4.AND.KFLN.EQ.21) CALL PY4ENT(NC+1,KFLC,KFLN,KFLN,
0115      &-KFLC,ECMC,X1,X2,X4,X12,X14)
0116       IF(NJET.EQ.4.AND.KFLN.NE.21) CALL PY4ENT(NC+1,KFLC,-KFLN,KFLN,
0117      &-KFLC,ECMC,X1,X2,X4,X12,X14)
0118       IF(MSTU(24).NE.0) GOTO 100
0119       DO 110 IP=NC+1,N
0120         K(IP,3)=K(IP,3)+MIN(MSTJ(115)/2,1)+(MSTJ(115)/3)*(NC-1)
0121   110 CONTINUE
0122
0123 C...Angular orientation according to matrix element.
0124       IF(MSTJ(106).EQ.1) THEN
0125         CALL PYXDIF(NC,NJET,KFLC,ECMC,CHI,THE,PHI)
0126         CALL PYROBO(NC+1,N,0D0,CHI,0D0,0D0,0D0)
0127         CALL PYROBO(NC+1,N,THE,PHI,0D0,0D0,0D0)
0128       ENDIF
0129
0130 C...Rotation and boost from radiative photon.
0131       IF(MK.EQ.1) THEN
0132         DBEK=-PAK/(ECM-PAK)
0133         NMIN=NC+1-MSTJ(115)/3
0134         CALL PYROBO(NMIN,N,0D0,-PHIK,0D0,0D0,0D0)
0135         CALL PYROBO(NMIN,N,ALPK,0D0,DBEK*SIN(THEK),0D0,DBEK*COS(THEK))
0136         CALL PYROBO(NMIN,N,0D0,PHIK,0D0,0D0,0D0)
0137       ENDIF
0138
0139 C...Generate parton shower. Rearrange along strings and check.
0140       IF(MSTJ(101).EQ.5) THEN
0141         CALL PYSHOW(N-1,N,ECMC)
0142         MSTJ14=MSTJ(14)
0143         IF(MSTJ(105).EQ.-1) MSTJ(14)=-1
0144         IF(MSTJ(105).GE.0) MSTU(28)=0
0145         CALL PYPREP(0)
0146         MSTJ(14)=MSTJ14
0147         IF(MSTJ(105).GE.0.AND.MSTU(28).NE.0) GOTO 100
0148       ENDIF
0149
0150 C...Fragmentation/decay generation. Information for PYTABU.
0151       IF(MSTJ(105).EQ.1) CALL PYEXEC
0152       MSTU(161)=KFLC
0153       MSTU(162)=-KFLC
0154
0155       RETURN
0156       END