Mwibanda/m4/ltsugar.m4

0001 # ltsugar.m4 -- libtool m4 base layer.                         -*-Autoconf-*-
0002 #
0003 # Copyright (C) 2004, 2005, 2007, 2008 Free Software Foundation, Inc.
0004 # Written by Gary V. Vaughan, 2004
0005 #
0006 # This file is free software; the Free Software Foundation gives
0007 # unlimited permission to copy and/or distribute it, with or without
0008 # modifications, as long as this notice is preserved.
0009
0010 # serial 6 ltsugar.m4
0011
0012 # This is to help aclocal find these macros, as it can't see m4_define.
0013 AC_DEFUN([LTSUGAR_VERSION], [m4_if([0.1])])
0014
0015
0016 # lt_join(SEP, ARG1, [ARG2...])
0017 # -----------------------------
0018 # Produce ARG1SEPARG2...SEPARGn, omitting [] arguments and their
0019 # associated separator.
0020 # Needed until we can rely on m4_join from Autoconf 2.62, since all earlier
0021 # versions in m4sugar had bugs.
0022 m4_define([lt_join],
0023 [m4_if([$#], [1], [],
0024        [$#], [2], [[$2]],
0025        [m4_if([$2], [], [], [[$2]_])$0([$1], m4_shift(m4_shift($@)))])])
0026 m4_define([_lt_join],
0027 [m4_if([$#$2], [2], [],
0028        [m4_if([$2], [], [], [[$1$2]])$0([$1], m4_shift(m4_shift($@)))])])
0029
0030
0031 # lt_car(LIST)
0032 # lt_cdr(LIST)
0033 # ------------
0034 # Manipulate m4 lists.
0035 # These macros are necessary as long as will still need to support
0036 # Autoconf-2.59 which quotes differently.
0037 m4_define([lt_car], [[$1]])
0038 m4_define([lt_cdr],
0039 [m4_if([$#], 0, [m4_fatal([$0: cannot be called without arguments])],
0040        [$#], 1, [],
0041        [m4_dquote(m4_shift($@))])])
0042 m4_define([lt_unquote], $1)
0043
0044
0045 # lt_append(MACRO-NAME, STRING, [SEPARATOR])
0046 # ------------------------------------------
0047 # Redefine MACRO-NAME to hold its former content plus `SEPARATOR'`STRING'.
0048 # Note that neither SEPARATOR nor STRING are expanded; they are appended
0049 # to MACRO-NAME as is (leaving the expansion for when MACRO-NAME is invoked).
0050 # No SEPARATOR is output if MACRO-NAME was previously undefined (different
0051 # than defined and empty).
0052 #
0053 # This macro is needed until we can rely on Autoconf 2.62, since earlier
0054 # versions of m4sugar mistakenly expanded SEPARATOR but not STRING.
0055 m4_define([lt_append],
0056 [m4_define([$1],
0057            m4_ifdef([$1], [m4_defn([$1])[$3]])[$2])])
0058
0059
0060
0061 # lt_combine(SEP, PREFIX-LIST, INFIX, SUFFIX1, [SUFFIX2...])
0062 # ----------------------------------------------------------
0063 # Produce a SEP delimited list of all paired combinations of elements of
0064 # PREFIX-LIST with SUFFIX1 through SUFFIXn.  Each element of the list
0065 # has the form PREFIXmINFIXSUFFIXn.
0066 # Needed until we can rely on m4_combine added in Autoconf 2.62.
0067 m4_define([lt_combine],
0068 [m4_if(m4_eval([$# > 3]), [1],
0069        [m4_pushdef([_Lt_sep], [m4_define([_Lt_sep], m4_defn([lt_car]))])]]dnl
0070 [[m4_foreach([_Lt_prefix], [$2],
0071              [m4_foreach([_Lt_suffix],
0072                 ]m4_dquote(m4_dquote(m4_shift(m4_shift(m4_shift($@)))))[,
0073         [_Lt_sep([$1])[]m4_defn([_Lt_prefix])[$3]m4_defn([_Lt_suffix])])])])])
0074
0075
0076 # lt_if_append_uniq(MACRO-NAME, VARNAME, [SEPARATOR], [UNIQ], [NOT-UNIQ])
0077 # -----------------------------------------------------------------------
0078 # Iff MACRO-NAME does not yet contain VARNAME, then append it (delimited
0079 # by SEPARATOR if supplied) and expand UNIQ, else NOT-UNIQ.
0080 m4_define([lt_if_append_uniq],
0081 [m4_ifdef([$1],
0082           [m4_if(m4_index([$3]m4_defn([$1])[$3], [$3$2$3]), [-1],
0083                  [lt_append([$1], [$2], [$3])$4],
0084                  [$5])],
0085           [lt_append([$1], [$2], [$3])$4])])
0086
0087
0088 # lt_dict_add(DICT, KEY, VALUE)
0089 # -----------------------------
0090 m4_define([lt_dict_add],
0091 [m4_define([$1($2)], [$3])])
0092
0093
0094 # lt_dict_add_subkey(DICT, KEY, SUBKEY, VALUE)
0095 # --------------------------------------------
0096 m4_define([lt_dict_add_subkey],
0097 [m4_define([$1($2:$3)], [$4])])
0098
0099
0100 # lt_dict_fetch(DICT, KEY, [SUBKEY])
0101 # ----------------------------------
0102 m4_define([lt_dict_fetch],
0103 [m4_ifval([$3],
0104         m4_ifdef([$1($2:$3)], [m4_defn([$1($2:$3)])]),
0105     m4_ifdef([$1($2)], [m4_defn([$1($2)])]))])
0106
0107
0108 # lt_if_dict_fetch(DICT, KEY, [SUBKEY], VALUE, IF-TRUE, [IF-FALSE])
0109 # -----------------------------------------------------------------
0110 m4_define([lt_if_dict_fetch],
0111 [m4_if(lt_dict_fetch([$1], [$2], [$3]), [$4],
0112         [$5],
0113     [$6])])
0114
0115
0116 # lt_dict_filter(DICT, [SUBKEY], VALUE, [SEPARATOR], KEY, [...])
0117 # --------------------------------------------------------------
0118 m4_define([lt_dict_filter],
0119 [m4_if([$5], [], [],
0120   [lt_join(m4_quote(m4_default([$4], [[, ]])),
0121            lt_unquote(m4_split(m4_normalize(m4_foreach(_Lt_key, lt_car([m4_shiftn(4, $@)]),
0122                       [lt_if_dict_fetch([$1], _Lt_key, [$2], [$3], [_Lt_key ])])))))])[]dnl
0123 ])